創幻股票選股指標公式源碼
❶ 請老師將下面源碼做個選股公式，要求選出「起爆」股票，謝謝
DIFF:=EMA(DCLOSE,12)-EMA(DCLOSE,26);
DEA:=EMA(DIFF,9),COLORCYAN;
VAR18:=BARSLAST(REF(CROSS(DIFF,DEA),1));
底背離:=REF(CLOSE,VAR18+1)>CLOSE AND DIFF>REF(DIFF,VAR18+1) AND CROSS(DIFF,DEA);
VAR19:=BARSLAST(REF(CROSS(DEA,DIFF),1));
頂背離:=REF(CLOSE,VAR19+1)<CLOSE AND REF(DIFF,VAR19+1)>DIFF AND CROSS(DEA,DIFF);
買入:ZIG(3,5)>REF(ZIG(3,5),1) AND REF(ZIG(3,5),1)<=REF(ZIG(3,5),2) AND REF(ZIG(3,5),2)<=REF(ZIG(3,5),3);
你的公式中沒有「起爆」。
❷ 請老師將下列源碼做個選股公式,要求選出"有牛"的股票
{顯示儀表盤=1} ;
范圍高A:=REFDATE(HHV(H,120),DATE)*1.05;
范圍低A:=REFDATE(LLV(L,120),DATE)*0.95;
MA24:=MA(C,24);
MA72:=MA(C,72);
MA200:=IF((MA(C,200)<=范圍高A AND MA(C,200)>=范圍低A) OR C>=MA(C,200),MA(C,200),DRAWNULL);
有牛:MA24<MA72 AND C>=MA72 AND MA72<MA200 AND C>=MA200;
❸ 如何自己寫股票條件選股公式源碼
初學者可以先用最簡單的方法寫好了就測試，比如c=10,那麼選出來的都是股價等於10塊錢的。條件選股只能是一個輸出比如下面這個簡單的公式：
A1:=MA(CLOSE,5);{5日均線}A2:=MA(CLOSE,10);{10日均線}A3:=MA(CLOSE,30);{30日均線}
B1:=A1>REF(A1,1);{5日均線往上翹}
B2:=A2>REF(A2,1);{10日均線往上翹}
B3:=A3>REF(A3,1);{30日均線往上翹}
AA:=A1>A2 AND A2>A3{多頭排列也就是說5日線在10日線之上和10日線在30日線之上}
XG:AA AND B1 AND B2 AND B3;{這句是總結上面所有需要輸出的意思}
這公式中上7行中都有個『=』號這個等於號是不輸出的意思，如果都去掉了就會出現軟體提示「條件選股只能一個輸出」的字眼。記住開頭冒號，結尾分號。
好了說到這里你應該會做簡單的條件選股公式了吧？會簡單的寫公式然後照著思路慢慢研究更深層的公式吧。
❹ 指標公式如何改寫成選股條件公式
【一品抄底】，是個副圖指標，既有線性輸出信號，也有買點提示信號，輸出類別眾多，就不是一個單獨的選股指標。如何修改、拆分出自己需要的【底部】選股信號，成為一個單獨的選股指標呢？如果還需要將【深坑】的信號，也單獨設置為選股指標，又該如何修改呢？在此先當做一個問題吧，繼續看了後面（二）、（三）小節的引路，相信你自己來就行了！
{一品抄底----創幻論壇一品茶緣編寫，通用副圖指標}
TYP := (HIGH + LOW + CLOSE)/3;
CCI:=(TYP-MA(TYP,14))/(0.015*AVEDEV(TYP,14));
A:=REF(C,1);
RSI:=SMA(MAX(C-A,0),6,1)/SMA(ABS(C-A),6,1)*100;
A1:=(C/MA(C,5)-1)*100<-10;
A2:=(C/MA(C,13)-1)*100<-10;
A3:=(C/MA(C,34)-1)*100<-15;
A4:=RSI<18;
A5:=CCI<-120;
A6:=COUNT(ABS(C/REF(C,1)-1)*100>=6,30)>=1;
底部:A1 AND A2 AND A3 AND A4 AND A5 AND A6,COLOR00FFFF,LINETHICK2;
CDSJ:=BARSLAST(底部);
ZF:=(C/REF(C,1)-1)*100;
深坑:IF(BETWEEN(CDSJ,0,5) AND L<=REF(C,CDSJ) AND ZF<=-5,-0.5,0),COLORFF0000,LINETHICK2;
機會:IF(CDSJ<=7 AND L<=REF(C,CDSJ),0.5,0),COLOR00FF00;
尋找選股信號的來源
所謂選股信號，多數都是屬於將已有的指標公式中具有買點類的信號特徵「剝離」出來。那麼，在指標中該保留哪些有用的源碼，刪除哪些無關的源碼呢？尋找選股信號的來源，就是最主要的過程。
尋找選股信號來源的方法，一般都是遵循從後往前尋找的原則。
具體步驟是：先找到發出指標信號的那行代碼，然後查看該行代碼中的所有條件，需要用到上面哪些源碼，再從後往前一一對應尋找出來；而其他無關的條件、修飾符號源碼，均可刪除。
舉例3：（本例子參考大慶老楊先生帖子，略有改動）
{股市馬經----副圖指標，源碼來自網路}
A1:3*SMA((C-LLV(L,55))/(HHV(H,55)-LLV(L,55))*100,5,1)-2*SMA((C-LLV(L,55))/(HHV(H,55)-LLV(L,55))*100,5,1);
黑馬線:EMA(A1,5),LINETHICK2,COLOR6600FF;
A2:=(黑馬線-REF(黑馬線,1))/REF(黑馬線,1)*100;
A3:=EMA(C,5);
A4:=((C-LLV(L,21))/(HHV(H,21)-LLV(L,21)))*100;
趨勢線:(MA(3*SMA(A4,6,1)-2*SMA(SMA(A4,5,1),5,1),2)),LINETHICK2,coloryellow;
A5:=(HHV(H,60)-C)/(HHV(H,60)-LLV(L,60))*100;
DRAWTEXT(FILTER(REF(黑馬線,1)>90 AND A2<0,7),黑馬線,'跑'),COLOR00FF00;
DRAWTEXT(CROSS(A1,黑馬線)AND 黑馬線<A5,黑馬線,'黑馬');
DRAWTEXT(CROSS(黑馬線,A5)AND 趨勢線<80,黑馬線,'追漲');
DRAWTEXT(CROSS(趨勢線,0)AND 黑馬線<40,5,'大黑馬');
底部:(A2<-10 AND A2>REF(A2,1))*25,colorred;
DRAWICON(底部 AND A3>REF(A3,1),25,4);
機會來臨:REF(IF((MA(C,5)-C)/C>0.04 AND (MA(C,10)-MA(C,5))/MA(C,5)>0.04,30,0),1),COLORF00FF0;
大勢已去:IF(CROSS(黑馬線,A1)AND 黑馬線>70 AND 趨勢線>80,90,100),COLORFF0000;
公式中涉及「買」的信號有黑馬、追漲、大黑馬、底部和機會來臨五個明顯的，另外還有一個畫圖標信號。
假如我們提取其中的【機會來臨】，仔細分析後，就是一句話：
機會來臨:REF(IF((MA(C,5)-C)/C>0.04 AND (MA(C,10)-MA(C,5))/MA(C,5)>0.04,30,0),1);
這個可看作簡單提取。
如果提取【大黑馬】的話，從後向前推，涉及趨勢線和黑馬線兩個定義，這部分都有用：
A1:3*SMA((C-LLV(L,55))/(HHV(H,55)-LLV(L,55))*100,5,1)-2*SMA((C-LLV(L,55))/(HHV(H,55)-LLV(L,55))*100,5,1);
黑馬線:EMA(A1,5),LINETHICK2,COLOR6600FF;
A4:=((C-LLV(L,21))/(HHV(H,21)-LLV(L,21)))*100;
趨勢線:(MA(3*SMA(A4,6,1)-2*SMA(SMA(A4,5,1),5,1),2)),LINETHICK2,coloryellow;
DRAWTEXT(CROSS(趨勢線,0) AND 黑馬線<40,5,'大黑馬');
（三）修改選股指標的方法
根據以上選股公式的特徵，結合尋找選股信號來源的方法，自己動手修改選股信號，應該就沒有太大的難度了！
舉例4：繼續承接上面（二）的例子。
修改步驟：
①先將線性輸出的A1、黑馬線、A4、趨勢線均限制輸出，方法很簡單，就是在他們的冒號後面直接加上等號=；
②再刪去修飾符LINETHICK2,COLOR6600FF：
③將本來是文字輸出的「黑馬線」修改成信號輸出；先將「黑馬線」三個字移動到最前面，並加上冒號：；然後保留符合黑馬線的限制條件CROSS(趨勢線,0) AND 黑馬線<40；同時刪除其餘無關的代碼，包括文字輸出函數DRAWTEXT、位置、括弧（）等。
修改成選股指標後的源碼如下：
A1:=3*SMA((C-LLV(L,55))/(HHV(H,55)-LLV(L,55))*100,5,1)-2*SMA((C-LLV(L,55))/(HHV(H,55)-LLV(L,55))*100,5,1);
黑馬線:=EMA(A1,5);
A4:=((C-LLV(L,21))/(HHV(H,21)-LLV(L,21)))*100;
趨勢線:=(MA(3*SMA(A4,6,1)-2*SMA(SMA(A4,5,1),5,1),2));
大黑馬:CROSS(趨勢線,0) AND 黑馬線<40;
舉例5：
下面附圖指標【大三浪】中，如何選出出現「買」字提示信號的選股指標？
{大三浪----創幻論壇一品茶緣編寫，通用副圖指標}
{大三浪指標使用說明:
均線粘合且多頭,長期未漲庄吸籌;
目標鎖定先跟蹤,出擊買入等豐收!}
{N:30,120,65;}
MA5:=MA(CLOSE,5);
MA21:=MA(CLOSE,21);
MA65:=MA(CLOSE,N);
多頭:=COUNT(MA21>MA65,10)=10;
GX:=MAX(MA5,MAX(MA21,MA65));
DX:=MIN(MA5,MIN(MA21,MA65));
粘合:=ABS(GX/DX-1)*100<=15;
多頭粘合:IF(多頭 AND 粘合,1,0),COLORFF00FF,POINTDOT,LINETHICK0;
DIFF:=EMA(CLOSE,12) - EMA(CLOSE,26);
DEA:=EMA(DIFF,9);
MACD:=2*(DIFF-DEA);
庄股:COUNT(MACD<0,10)=10,COLORFFFF00,POINTDOT,LINETHICK0;
目標:IF(多頭 AND 粘合 AND 庄股,5,0),COLORFFFFFF,LINETHICK2;
跟蹤:IF(目標,BARSLAST(CROSS(目標,0))+1,0),COLOR00FF00,POINTDOT,LINETHICK2;
出擊:IF(CROSS(0.1,目標) AND CROSS(MACD,0),8,0),COLOR00FFFF,LINETHICK2;
MJSJ:=BARSLAST(出擊>0);
漲幅:IF(MJSJ<=120,(C/REF(C,MJSJ)-1)*100,0),COLOR0000FF,POINTDOT,LINETHICK0;
日漲:IF(MJSJ<=120,漲幅/MJSJ,0),COLORFFFFFF,POINTDOT,LINETHICK0;
TPX:=MIN(MA65*1.15,MA21*1.13);
突破:IF(CROSS(C,TPX) AND 粘合 AND MA65>REF(MA65,1),10,0),COLOR0000FF,LINETHICK2;
{以下設置副圖顯示方式}
STICKLINE(多頭粘合,0,1,8,0),COLORFF00FF;
STICKLINE(庄股,0,MACD*10,8,0),COLORFFFF00;
DRAWTEXT(出擊=8,10,'★買'),COLOR00FFFF;
VERTLINE(CROSS(漲幅,20) AND COUNT(CROSS(漲幅,20),MJSJ)=1,2),COLOR0000FF; 根據選股指標的步驟，一步一步來：
①首先找到出現「★買」提示的一行代碼，發現她其實就是「出擊」的信號；
②從後往前，找到「出擊」信號的條件，發現他與「目標」、MACD有關；
再次往前尋找，又發現「目標」信號的條件，與「多頭」、「粘合」、「庄股」三個條件有關，由此，保留相關條件代碼，其餘刪除，如下：
{N:30,120,65;}
MA5:=MA(CLOSE,5);
MA21:=MA(CLOSE,21);
MA65:=MA(CLOSE,N);
多頭:=COUNT(MA21>MA65,10)=10;
GX:=MAX(MA5,MAX(MA21,MA65));
DX:=MIN(MA5,MIN(MA21,MA65));
粘合:=ABS(GX/DX-1)*100<=15;
DIFF:=EMA(CLOSE,12) - EMA(CLOSE,26);
DEA:=EMA(DIFF,9);
MACD:=2*(DIFF-DEA);
庄股:COUNT(MACD<0,10)=10,COLORFFFF00,POINTDOT,LINETHICK0;
目標:IF(多頭 AND 粘合 AND 庄股,5,0),COLORFFFFFF,LINETHICK2;
出擊:IF(CROSS(0.1,目標) AND CROSS(MACD,0),8,0),COLOR00FFFF,LINETHICK2;
③限制輸出數量，只保留「出擊」信號的輸出，其他的輸出信號均加上等號=加以限制輸出；
④刪除多餘的修飾符號，如：COLORFFFF00,POINTDOT,LINETHICK0等。
⑤IF格式也可簡化，只保留需要的條件，輸出信號自動為1。「出擊」兩字也可修改為「買」。
修改完最後保留的源碼如下：
{大三浪----選股指標}
{N:30,120,65;}
MA5:=MA(CLOSE,5);
MA21:=MA(CLOSE,21);
MA65:=MA(CLOSE,N);
多頭:=COUNT(MA21>MA65,10)=10;
GX:=MAX(MA5,MAX(MA21,MA65));
DX:=MIN(MA5,MIN(MA21,MA65));
粘合:=ABS(GX/DX-1)*100<=15;
DIFF:=EMA(CLOSE,12) - EMA(CLOSE,26);
DEA:=EMA(DIFF,9);
MACD:=2*(DIFF-DEA);
庄股:=COUNT(MACD<0,10)=10;
目標:=IF(多頭 AND 粘合 AND 庄股,5,0);
買:CROSS(0.1,目標) AND CROSS(MACD,0); 導入選股指標的途徑
①修改完後的選股指標源碼，想做成選股指標，並非放在指標系統之下的【技術指標】分類，一般是放入【條件選股】分類；便於設置預警、自動選股。
②還可將選股指標加入交易系統中，但需要注意的是：輸出信號必須為英文單詞的買入ENTERLONG、賣出EXITLONG信號。在應用時，飛狐軟體輸入該交易系統指標名稱，即可在主圖自動顯示買賣信號的提示。
源碼如下：
ENTERLONG:CROSS(MA(C,3),MA(C,8));----表示輸出多頭買入信號。
EXITLONG:CROSS(MA(C,8),MA(C,3));----表示輸出空頭賣出信號。
❺ 請高手把源碼改成選股公式 我想讓它選出在最後出現"買」字的股票
選股公式是：
-----------------------
Z:=ZIG(3,5)；
(Z>REF(Z,1)) AND (REF(Z,1)<=REF(Z,2));
-----------------------
你找到的這個指標看過去顯示的買入或賣出都十分理想，但直接用它就不行了。因為 ZIG 是個未來函數。你上網找一下未來函數的問題吧。
❻ 指標公式改選股公式和預警公式
N1:=5;N2:=10;
LC:=REF(CLOSE,1);
RSI5:=SMA(MAX(CLOSE-LC,0),N1,1)/SMA(ABS(CLOSE-LC),N1,1)*10;
RSI10:=SMA(MAX(CLOSE-LC,0),N2,1)/SMA(ABS(CLOSE-LC),N2,1)*10;
VAR1:=C-REF(C,1);
VAR2:=100*EMA(EMA(VAR1,6),6)/EMA(EMA(ABS(VAR1),6),6);
MA5:=EMA(C,5);
MA13:=EMA(C,13);
UP:=DRAWLINE(L=LLV(L,BARSLAST(CROSS(MA13,MA5))+1),LLV(L,BARSLAST(CROSS(MA13,MA5))+1),H=HHV(H,BARSLAST(CROSS(MA5,MA13))+1),HHV(H,BARSLAST(CROSS(MA5,MA13))+1),0);
DOWN:=DRAWLINE(H=HHV(H,BARSLAST(CROSS(MA5,MA13))+1),HHV(H,BARSLAST(CROSS(MA5,MA13))+1),L=LLV(L,BARSLAST(CROSS(MA13,MA5))+1),LLV(L,BARSLAST(CROSS(MA13,MA5))+1),0);
BT:=(LLV(VAR2,2)=LLV(VAR2,7) AND COUNT(VAR2<0,2) AND CROSS(VAR2,MA(VAR2,2))) AND REF(DOWN,1)<REF(DOWN,2) AND UP>REF(DOWN,1);
TJ1:=REF(DOWN,1)<REF(DOWN,2) AND UP>REF(DOWN,1) AND C<HHV(H,21)*0.82;
HR:=HHV(HIGH,55);
HRY:=LLV(LOW,55);
HRY11:=HR*HRY;
HRY33:=SQRT(HRY11);
TJ2:=REF(DOWN,1)<REF(DOWN,2) AND UP>REF(DOWN,1) AND C<HRY33;
XG:TJ2 OR TJ1 OR BT;
不過這指標里有未來函數，最好不要用於選股
❼ 股票指標公式改為選股公式，源碼如下：
N:=30;
RSV:=(CLOSE-LLV(LOW,N))/(HHV(HIGH,N)-LLV(LOW,N))*100;
K:=SMA(RSV,5,1);
D:=SMA(K,3,1);
J:=3*K-2*D;
AA3:=(HHV(HIGH,21)-CLOSE)/(HHV(HIGH,21)-LLV(LOW,21))*100-10;
AA4:=(CLOSE-LLV(LOW,21))/(HHV(HIGH,21)-LLV(LOW,21))*100;
AA5:=SMA(AA4,13,8);
主力線:=EMA(J,6);
走勢:=CEILING(SMA(AA5,13,8));
XG:CROSS(走勢,主力線) AND 主力線<80;
❽ 在哪裡可以學習編寫條件選股公式源碼
股票公式代碼都很簡單,
可以從修改選股公式開始,編寫一些簡單的技術指標開始,系統中有很多指標都是公開源代碼的.
但光輝編寫公式,只是一方面,常用的技術指標公式具體的演算法,也要熟練掌握.
書好像有本叫,
量化思路：證券技術指標編寫技法
,雖然和現在的有些差異,但大體是一樣的,這應該是講股票編程最簡單的書了.
❾ 請高手幫忙將股票指標公式改為選股公式，源碼如下：
額，源碼你沒打出來啊
❿ 通達信經典實用選股公式(125個常用公式源碼)